The Table of Marks of .

 

In this section table of marks of the sporadic simple Mathieu group is determined. We assume that the maximal subgroups of are known, and that we have already computed their tables of marks. An implementation in GAP of the procedures described in sections 4 and 5 is used to determine the fusion map from the maximal subgroups into . We give only a short account of the development. This should give an impression of the amount and the type of work involved.

The permutation representation of we will work with is taken from the GAP library of primitive groups.

   gap> m24:= AllPrimitiveGroups(Size, 48 * Product([20..24]))[1];;
   gap> m24.name:= "m24"; 
   gap> m24.generators;
   [ ( 1, 7,12,16,19,21, 6)( 2, 8,13,17,20, 5,11)( 3, 9,14,18, 4,10,15), 
     ( 2,14,18,20, 8)( 3, 7,12,13,19)( 4,21,17,15,10)( 5,11,16, 6, 9), 
     ( 1,22)( 2,10)( 3,14)( 4,17)( 8,15)( 9,11)(13,20)(19,21), 
     ( 3,19)( 4,14)( 5,20)( 6,10)( 8,15)(11,18)(17,21)(22,23), 
     ( 2,10)( 3,13)( 4,11)( 5,18)( 8,15)( 9,17)(14,20)(23,24) ]

A complete list of conjugacy classes of maximal subgroups is given in Table 2 as it is found in the ATLAS ([Conway et al. 1985], p. 94). This is based on [Todd 1966] and [Choi 1972]. For a detailed combinatorial description see also [Conway 1971], [Curtis 1976], and [Curtis 1977].

  
Table 2: The maximal subgroups of .

Table 2 lists for each maximal subgroup of its name, its index in and its order. The specification describes the subgroup by the kind of object it stabilizes. We furthermore list the name that is used in the GAP session and the number of conjugacy classes of subgroups of each maximal subgroup.

In GAP, the maximal subgroups of are then constructed as stabilizers according to the above table or by explicit generating permutations.

   m23:= Stabilizer(m24, 24);  m23.name:= "m23";
   
   n22:= Stabilizer(m24, [23, 24], OnSets);  n22.name:= "n22";
   
   trio:=[[1,2,3,4,5,6,12,16],[8,10,13,20,21,22,23,24],[7,9,11,14,15,17,18,19]];
   ea8:= Stabilizer(m24, trio[2], OnSets);  ea8.name:= "ea8";
   
   duum:= [[1,5,8,10,11,14,17,18,20,21,23,24], [2,3,4,6,7,9,12,13,15,16,19,22]];
   m12:= Stabilizer(m24, duum[1], OnSets);  m12.name:= "m12";
   n12:= Normalizer(m24, m12);  n12.name:= "n12";
   
   sextet:= [[1,12,16,18],[2,15,21,23],[3,14,22,24],[4,7,8,20],[5,9,17,19]];
   grp:= m24;  for four in sextet do grp:= Stabilizer(grp, four, OnSets); od;
   e3s6:= Normalizer(m24, grp);  e3s6.name:= "e3s6";
   
   n21:= Stabilizer(m24, [22..24], OnSets);  n21.name:= "n21";
   trio:=[[1,6,10,11,12,13,16,18],[2,3,7,8,9,15,19,24],[4,5,14,17,20,21,22,23]];
   grp:= Stabilizer(Stabilizer(m24, trio[1], OnSets), trio[2], OnSets);
   nea:= Normalizer(m24, grp);  nea.name:= "nea";
   
   l23:= Subgroup(m24,
   [(1,7)(2,16)(3,14)(4,9)(5,6)(8,21)(10,11)(12,19)(13,15)(17,24)(18,20)(22,23),
    (1,23,2)(3,10,16)(4,19,20)(5,8,22)(6,24,17)(7,18,11)(9,21,13)(12,14,15)]);
   l23.name:= "l23";
   
   l7:= Subgroup(m24,
   [(1,14)(2,20)(3,9)(4,16)(5,12)(6,24)(7,10)(8,21)(11,23)(13,19)(15,18)(17,22),
    (1,11,18)(2,7,5)(3,21,16)(4,20,15)(6,24,8)(9,14,10)(12,13,19)(17,23,22)]);
   l7.name:= "l7";
   
   m24.max:= [m23, n22, ea8, n12, e3s6, n21, nea, l23, l7];

The computation of all but two of the tables of marks of the maximal subgroups via the lattice of subgroups is almost automatic. It requires up to 80 MB of main memory and some hours of cpu time. In addition to the permutation representation of a maximal subgroup M one has to supply a complete list of representatives of perfect subgroups of M as input for the lattice program.

For the maximal subgroups and (and for inside ) the method described here has been applied to obtain their table of marks together with a list of representatives of the conjugacy classes of subgroups.

We will skip quickly through the automatic part of the strategy, and just report some interesting figures.

The disjoint union of the conjugacy classes of maximal subgroups of consists of 7354 subgroups which initially fall into 116 -classes, i.e. which have 116 different orders. The refinement via RefineClassesFrame yields 445 classes. This tells us that there are at least 445 different isomorphism types of subgroups of (plus itself).

The inspection of the Sylow subgroups via CheckSylowFrame yields the fusion of the 6 -classes of Sylow subgroups. The -class of the trivial subgroups is detected and fused. Moreover, 31 -classes of 2-subgroups inside the Sylow 2-subgroup are fused. The Sylow p-subgroups for p = 5, 7, 11, and 23 are cyclic, so here is nothing left for CheckSylowFrame to do. The Sylow 3-subgroup has order , here are some -classes with more than one element. The routine CheckSylowFrame will prove most powerful inside the Sylow 2-subgroup of order which contains lots of classes of subgroups.

The application of CheckNormalizerFrame yields the fusion of 36 more classes. Then 302 fusions of single subgroups are caused by ConcludeFrame. We are left with 320 unfinished classes.

Since has this small permutation representation on 24 points, and all maximal subgroups are given explicitly as subgroups of this permutation group on 24 points, we have access to a representative for each conjugacy class of subgroups of each maximal subgroup of . Thus, we can use these permutation groups in order to distinguish groups which are not conjugate in .

Let U be a subgroup of . Then U acts on 24 points and the lengths of the orbits of U give a partition of 24. If U' is a subgroup of which is conjugate to U then . If we use this criterion on the -classes then 269 of them split into two or more classes. A further refinement with RefineClassesFrame yields a total of 1453 classes. Then CheckSylowFrame can fuse 523 classes inside the Sylow 2-subgroup and three classes inside the Sylow 3-subgroup. Moreover, CheckNormalizerFrame can fuse 479 classes. Then ConcludeFrame causes 1722 fusions of elements of . We are left with 93 unfinished classes.

The representatives of the conjugacy classes of subgroups of the maximal subgroups of can also be used to determine the size of their normalizers in . Of course, the normalizers of conjugate subgroups have the same size. This criterion can be used to split one of the -classes of subgroups of order 4 into three classes. RefineClassesFrame then yields a total of 1510 classes. CheckSylowFrame fuses 4 classes inside the Sylow 2-subgroup. CheckNormalizerFrame fuses 20 further classes. ConcludeFrame causes one additional fusion in .

Checking the sizes of normalizers of the -classes of small size (4, 8, 12, and 16) together with the application of RefineClassesFrame leads to a total of 1527 classes.

The remaining problem is quite small; we are faced with a pre-fusion map where only 28 of the -classes have more than one element. These classes contain subgroups of order 16, 60 [2 classes], 120 [3 classes], 168, 240 [3 classes], 336, 360 [2 classes], 480, 660, 720 [4 classes], 1320, 1344, 1440, 2520, 7920, 20160 [2 classes], 40320, and 443520.

Five of these classes can be solved by looking at intersections of the maximal subgroups.

The point stabilizer m23 and the duad stabilizer n22 intersect in a group of size 443520,

   gap> Size(Intersection(m23, n22));
   443520

(which is, of course, the 2-point stabilizer ) and, since the -class of groups of this size consists of a conjugacy class of subgroups of and a conjugacy class of subgroups of , we can fuse this class.

The point stabilizer m23 and the triad stabilizer n21 intersect in a group of size 40320 (which is , the duad stabilizer in ), so do the duad stabilizer n22 and n21.

   gap> Size(Intersection(m23, n21));
   40320
   gap> Size(Intersection(n22, n21));
   40320

Therefore, the three elements in the -class of groups of that size belong to one single conjugacy class of subgroups of .

We look at the size of the intersection of ea8 and the stabilizer of the point 1 in

   gap> Size(Intersection(ea8, Stabilizer(m24, 1))); 
   20160

and can decide for one of the -classes of groups of size 20160, that they indicate a single conjugacy class.

Similarly we find a group of order 7920 ( ) as the intersection of n12 and m23 and a group of order 1440 ( ) as the intersection of n22 and n12. This allows to fuse the -classes of groups of these orders.

After the fusion of these five classes ConcludeFrame causes 23 further fusions. In particular, the class of groups of order 660 is fused into a singleton, and consequently the class of groups of order 1320 can be identified as the class of their normalizers, whence it also can be fused.

The -class of groups of order 480 consists of two elements, a subgroup of n12 and a subgroup of e3s6. The duums stabilized by each of these groups is exhibited by passing to the derived subgroups. Let rep1 and rep2 be representatives of the two elements in the -class and let der1 and der2 be their respective derived subgroups. We determine their orbits on the 24 points and an element g of that maps the duum of rep2 to that of rep1 (and thereby conjugates rep2 into n12).

   gap> o1:= Orbits(der1, [1..24]);
   [ [ 1, 23, 17, 24, 20, 5, 21, 10, 18, 8, 14, 11 ], 
     [ 2, 15, 13, 7, 19, 9, 16, 4, 22, 6, 12, 3 ] ]
   gap> o2:= Orbits(der2, [1..24]);
   [ [ 1, 11, 9, 4, 13, 22, 24, 7, 21, 2, 18, 5 ], 
     [ 3, 23, 8, 16, 15, 14, 6, 17, 12, 20, 10, 19 ] ]
   gap> g:= RepresentativeOperation(m24, Set(o2[1]), Set(o1[1]), OnSets);
   ( 2, 5,10,16, 4, 8,19,12, 3, 7,11,23,22,17,13,14, 6,15, 9,24,21,18,20)

The index of the subgroups in n12 is relatively small (396), and we can find a conjugating element inside n12.

   gap> h:= RepresentativeOperation(n12, rep1, rep2^g);
   ( 2,19, 6,15)( 3,22,16, 7)( 4,13)( 9,12)(10,24,14,17)(18,20,23,21)
   gap> rep1^h = rep2^g;
   true

We thus have explicitely shown that rep1 and rep2 are conjugate in and can now fuse the corresponding -class. ConcludeFrame then fuses all but one of the remaining classes.

The remaining -class of groups of order 16 consists of two elements. Each of them is the image under f of five elements of , where two are conjugacy classes of subgroups of nea, two of e3s6 and one of ea8.

Let rep1 and rep2 be representatives of the two elements in that -class. Again we look at the orbits of these groups on the 24 points.

   gap> Orbits(rep1, [1..24]);
   [ [ 1, 6, 10, 11, 13, 18, 16, 12 ], 
     [ 2, 3, 8, 7, 14, 9, 19, 23, 15, 5, 20, 4, 24, 17, 21, 22 ] ]
   gap> Orbits(rep2, [1..24]);
   [ [ 1, 6, 10, 11, 13, 18, 16, 12 ], 
     [ 2, 3, 7, 4, 8, 19, 5, 9, 21, 24, 23, 22, 15, 14, 17, 20 ] ]

The groups rep1 and rep2 both stabilize the same octad and they are not conjugate in the octad stabilizer ea8. Therefore they are not conjugate in and this class splits.

Finally the table of marks of can be computed via InducedFrame, a program that implements the induction formula 2.2. The number of subgroups of can now be derived from that table by means of Lemma 1.3.

   gap> tom:= InducedFrame(frame);;
   gap> Length(tom.subs);
   1529

Out of the 704 divisors of the order of only 117 occur as orders of subgroups of . Table 3 in the appendix lists for each such order the number of conjugacy classes of subgroups with that order and the total number of subgroups in these classes. The most popular orders among the conjugacy classes are 32 (212 classes) and 64 (209 classes). 32 is also the most popular order among the subgroups (186438483 subgroups). On the other hand, there are 44 conjugacy classes which are uniquely determined by the order of the subgroups they contain.